엑셀 괄호 안 문자 추출 공식 사용법 :: 엑셀 함수 공식

괄호 안 문자 추출 공식 사용법 및 실전예제 총정리

기본 공식

=MID(셀,FIND("(",셀)+1,FIND(")",셀,FIND("(",셀)+1)-FIND("(",셀)-1)

응용 공식

=MID(셀,FIND("(",셀,시작위치)+1,FIND(")",셀,FIND("(",셀)+1+시작위치)-FIND("(",셀)-1+시작위치)

엑셀 2013 이후 버전을 사용 중 경우, [빠른채우기] 기능을 사용하면
더욱 편리하게 문자를 추출할 수 있습니다.

인수	설명
셀	괄호 안 문자를 추출할 대상 셀 입니다.
시작위치 [응용공식]	문자열에 괄호가 한 쌍 이상일 경우, 두번째 또는 세번째 괄호가 문자열에서 시작하는 위치입니다.

오빠두엑셀의 강의 예제파일은 여러분을 위해 자유롭게 제공하고 있습니다.

셀 안의 텍스트 문자열 중 '괄호 안에 있는 텍스트 또는 숫자'만 추출하는 공식입니다. 만약 텍스트 문자열에 괄호가 한 쌍 이상 있을 경우, 첫번째 괄호 안의 문자만 추출합니다.

따라서 텍스트 문자열에 괄호가 여러개 있을 경우, 응용 공식을 이용하거나 빠른채우기를 사용하여 괄호 안 문자를 추출합니다.

괄호가 한 쌍만 있는 경우 [예: LG선풍기(220V)]

=MID(셀,FIND("(",셀)+1,FIND(")",셀,FIND("(",셀)+1)-FIND("(",셀)-1)
="220V" ' 올바른 값이 반환됩니다.

괄호가 여러 개 있을 경우 [예: LG (레드)선풍기 (특가)]

■ 일반 공식
=MID(셀,FIND("(",셀)+1,FIND(")",셀,FIND("(",셀)+1)-FIND("(",셀)-1)
="레드" → 첫번째 괄호 안의 문자를 추출합니다.

■ 응용 공식
=MID(셀,FIND("(",셀,11)+1,FIND(")",셀,FIND("(",셀)+1+11)-FIND("(",셀)-1+11)
="특가" → 두번째 괄호 안의 문자를 추출합니다.

FIND 함수를 사용하여 시작괄호"(" 의 시작위치를 구합니다.
=FIND("(","LG선풍기(220V)")
=6 ' 시작괄호 "(" 의 위치인 6을 반환합니다.
시작괄호 이후에 있는 닫힘괄호")" 의 위치를 구합니다.
=FIND(")","LG선풍기(220V)",FIND("(","LG선풍기(220V)")+1)
=FIND(")","LG선풍기(220V)",6+1)
=FIND(")","LG선풍기(220V)",7)
=11 ' 닫힘괄호 ")" 의 위치인 11을 반환합니다.
MID 함수로 괄호 사이의 문자를 추출합니다.
=MID(셀,FIND("(",셀)+1,FIND(")",셀,FIND("(",셀)+1)-FIND("(",셀)-1)
=MID("LG선풍기(220V)",6+1,11-6-1)
=MID("LG선풍기(220V)",7,4)
=220V

엑셀 2013 이후 버전을 사용 중일 경우, '빠른 채우기' 기능으로 괄호 안의 문자를 더욱 빠르게 추출 할 수 있습니다. 방법은 아주 간단합니다.

첫번째 셀에 괄호 안 문자를 입력합니다.
괄호 안 추출 할 문자를 첫번째 셀에 입력합니다.
괄호 안 문자를 추출할 대상 범위를 선택한 뒤, '홈' - '채우기' - '빠른채우기'를 클릭합니다.
(또는 단축키 Ctrl + E를 입력합니다.)

'채우기' - '빠른채우기'를 클릭합니다. (단축키 : Ctrl + E)
괄호 안 문자 추출이 완료되었습니다.
괄호 안 문자 추출이 완료됩니다.

5 6 투표

게시글평점