엑셀 오른쪽 부터 문자 찾기 공식
엑셀 오른쪽부터 문자 찾기 목차 바로가기
함수 공식
=FIND("|",SUBSTITUTE(셀,문자,"|",(LEN(셀)-LEN(SUBSTITUTE(셀,문자,"")))/LEN(문자)))
인수 설명
| 인수 | 설명 |
| 셀 | 오른쪽부터 검색할 전체 문자열이 입력된 셀 또는 전체 문자열입니다. |
| 문자 | 검색할 문자입니다. |
| | | 문자열 안에 포함되지 않은 특수문자를 입력합니다. 만약 문자열 안에 세로바(|)가 포함되어 있을 경우, 세로바 대신 다른 특수문자(예: *, ~ 등)을 입력합니다. |
예제파일 다운로드
오빠두엑셀의 강의 예제파일은 여러분을 위해 자유롭게 제공하고 있습니다.
- [엑셀공식] 엑셀 오른쪽 부터 문자 찾기 공식예제파일
호환성
운영체제 호환성 Windows 버전 모든 엑셀 버전에서 사용 가능합니다. Mac 버전 모든 엑셀 버전에서 사용 가능합니다. 사용된 기초 함수
엑셀 오른쪽부터 문자 찾기 공식 알아보기
공식 설명
엑셀 오른쪽 부터 문자 찾기 공식은 셀 안에 입력된 문자열의 오른쪽 부터 문자를 찾은 뒤, 문자의 위치를 반환하는 함수입니다. 기존의 FIND 함수는 문자열의 왼쪽부터 반환하는 문제가 있어, 문자열의 오른쪽부터 문자를 검색해야 할 경우 이번 포스트에서 소개해드린 공식을 사용합니다.
공식의 동작원리
- 문자열에서 찾는 문자를 제외한 다른 문자의 개수를 셉니다.
=LEN("사과밭 사과나무 사과열렸네")-LEN(SUBSTITUTE("사과밭 사과나무 사과열렸네","사과",""))
=14-LEN("밭 나무 열렸네")
=14-8
=6 - 문자열에서 찾는 문자의 마지막 순번을 찾기 위해 계산된 값을 찾는 문자의 문자개수로 나눠줍니다.
=(LEN("사과밭 사과나무 사과열렸네")-LEN(SUBSTITUTE("사과밭 사과나무 사과열렸네","사과","")))/LEN("사과")
=6/2
=3 - 문자열에서 n번째 위치한 찾는 문자를 특수문자로 변경합니다.
=SUBSTITUTE("사과밭 사과나무 사과열렸네","사과","|",3)
="사과밭 사과나무 |열렸네" - 문자열에서 특수문자가 위치한 순번을 반환합니다.
'특수문자의 위치는 문자열에서 찾는 문자 중 마지막으로 위치한 문자의 순번과 동일합니다.
=FIND("|",SUBSTITUTE(셀,문자,"|",(LEN(셀)-LEN(SUBSTITUTE(셀,문자,"")))/LEN(문자)))
=FIND("|","사과밭 사과나무 |열렸네")
=10
- 문자열에서 찾는 문자를 제외한 다른 문자의 개수를 셉니다.
