엑셀 MeasureRange 함수 사용법 및 전체 명령문 :: 셀 넓이 병합여부 확인

'###############################################################
'오빠두엑셀 VBA 사용자지정함수 (https://www.oppadu.com)
'■ MeasureRange 명령문
'■ 선택된 범위의 병합여부를 확인합니다.
'■ 인수 설명
'_____________Rng           : 크기 및 병합여부를 확인할 셀(범위)입니다.
'_____________FirstCellOnly : True일 경우 범위의 첫번째 셀의 크기만 반환합니다.
'■ 반환값
'_____________배열을 반환합니다. {넓이(pt), 높이(pt), 병합여부(Boolean)}
'###############################################################
 
Function MeasureRange(Rng As Range, Optional FirstCellOnly As Boolean = False)
 
Dim WS As Worksheet
Dim iCol As Long: Dim iRow As Long
Dim iCols As Long: Dim iRows As Long
Dim dblW As Double: Dim dblH As Double
Dim i As Long
Dim vaMeasure As Variant
 
With Rng
    Set WS = .Parent
    iCol = .Column
    iRow = .Row
    If FirstCellOnly = False Then iCols = Rng.Columns.Count Else iCols = .Offset(, 1).Column - iCol
    If FirstCellOnly = False Then iRows = Rng.Rows.Count Else: iRows = .Offset(1, 0).Row - iRow
End With
 
For i = 1 To iCols
    dblW = dblW + WS.Cells(iRow, iCol + i - 1).ColumnWidth
Next
 
For i = 1 To iRows
    dblH = dblH + WS.Cells(iRow + i - 1, iCol).RowHeight
Next
 
ReDim vaMeasure(0 To 2)
vaMeasure(0) = dblW
vaMeasure(1) = dblH
vaMeasure(2) = Rng.MergeCells
 
MeasureRange = vaMeasure
 
End Function

Sub Test()
 
Dim vaMeasure As Variant
 
vaMeasure = MeasureRange(Selection)
 
MsgBox "선택한 셀의 넓이는 " & vaMeasure(0) & "pt 입니다." & vbNewLine & _
    "선택한 셀의 높이는 " & vaMeasure(1) & "pt 입니다." & vbNewLine & _
    "선택한 셀의 병합여부는 [ " & vaMeasure(2) & " ] 입니다."
 
End Sub