엑셀 매크로 반복작업 실행 :: Set_Routine 명령문

'----------------------------
'아래 명령문을 새로운 모듈 안에 붙여넣기 후 사용합니다.
'----------------------------
 
Option Explicit
 
Public blnRepeat As Boolean
Public TimeToRun As Double
Dim tmpDate As String
 
Sub Set_Routine(CodeToRun As String, Optional s As Long = 5, Optional m As Long = 0, Optional UntilTime As String, Optional UntilDate As String, Optional CodeToStop As String)
 
'###############################################################
'오빠두엑셀 VBA 사용자지정함수 (https://www.oppadu.com)
'▶ Set_Routine 함수
'▶ 배열을 범위 위로 반환합니다.
'▶ 인수 설명
'_____________CodeToRun     : 반복 실행할 명령문입니다. 인수가 있을 경우, 명령문(인수) 형태로 입력합니다. 텍스트로만 입력 가능합니다.
'_____________s             : 명령문을 반복할 초 단위입니다. 기본값은 5 입니다.
'_____________m             : 명령문을 반복할 분 단위 입니다. 기본값은 0 입니다.
'_____________UntilTime     : 명령문의 반복을 종료할 시간입니다. UntilTime이 입력되면 UntilDate도 반드시 입력되어야 합니다.
'_____________UntilDate     : 명령문의 반복을 종료할 날짜입니다. UntilDate이 입력되면 UntilTime도 반드시 입력되어야 합니다.
'_____________CodeToStop    : 명령문의 반복을 종료하면서 실행할 명령문입니다.
'▶ 사용 예제
'Start_Scheduler "Test"
'Stop_Scheduler "Test"
'##############################################################
 
If UntilTime <> "" And UntilDate <> "" Then
    If DateValue(CStr(UntilDate)) + TimeValue(UntilTime) <= Now Then
        Stop_Routine CodeToRun, s, m, UntilTime, UntilDate, CodeToStop
        If CodeToStop <> "" Then Application.Run CodeToStop
        Exit Sub
    End If
End If
 
If blnRepeat = False Then Application.Run CodeToRun: blnRepeat = True
 
TimeToRun = Now + TimeSerial(0, m, s)
Application.OnTime TimeToRun, "'ScheduleWork """ & CodeToRun & """," & s & "," & m & ",""" & UntilTime & """,""" & UntilDate & """,""" & CodeToStop & """'"
blnRepeat = True
 
End Sub
 
Sub Stop_Routine(CodeToRun As String, Optional s As Long = 5, Optional m As Long = 0, Optional UntilTime As String, Optional UntilDate As String, Optional CodeToStop As String)
 
On Error Resume Next
blnRepeat = False
Application.OnTime TimeToRun, "'ScheduleWork """ & CodeToRun & """," & s & "," & m & ",""" & UntilTime & """,""" & UntilDate & """,""" & CodeToStop & """'", , False
 
End Sub
 
Sub ScheduleWork(CodeToRun As String, s As Long, m As Long, UntilTime As String, UntilDate As String, CodeToStop As String)
 
Application.Run CodeToRun
Call Set_Routine(CodeToRun, s, m, UntilTime, UntilDate, CodeToStop)
 
End Sub