(고수님들 도와주세요ㅜㅜ) 특정 단어를 포함하면서 월별 총 갯수 구하는 방법

@쭈꾸링 님 저도 아직은 초보수준이라서 대답이 될지는 모르겠지만, 제가 아는선에서 답변드리면

D셀의 넣는 식은 countifs를 이용해서

=COUNTIFS($A$2:$A$4824,">="&DATE(2024,1,1),$A$2:$A$4824,"<"&DATE(2024,2,1),$C$2:$C$4824,"뇌*")

이렇게 넣으시고, 2월이면 중간에 날짜만 2.1, 3.1로 수정하면 2월달 내역입니다.

날짜함수가 싫으시면 차라리 중간에 열하나 삽입하거나 마지막열을 추가해서 A열의 날짜를 월별로 구분해놓게 해서 하는방법도 있습니다.

=TEXT(A2,"m월")

이려면 위 수식을 마지막행에 추가해서 한다면 J2열에 저 수식을 입력하고 밑으로 채워넣기해서 쓰면

D월의 수식을

=COUNTIFS($J$2:$J4824,"1월",$C$2:$C4824,"뇌*")

또다른건 위데이터를 표로만들면 범위지정을 머릿말로 대체할수 있으니 그것도 고려해보시고,

F열은 길어서 보시기 편하게 할께요

=SUMPRODUCT(
(A2:A4824 >= DATE(2024, 1, 1)) *
(A2:A4824 < DATE(2024, 2, 1)) *
(
ISNUMBER(SEARCH("귀가", B2:B4824)) +
ISNUMBER(SEARCH("기타", B2:B4824))
)
)

이식은 1월이고, 2월은 날짜면 변경하시면 됩니다. 아니면 J열에 월별로 치한한것을 대입하셔도 되구요

이런식으로 해도 될겁니다. 2월이면 저 수식에 들어갈 1월을 2월로 바꾸면 되구요

마지막 H열도

=SUMPRODUCT(
($A$2:$A$4824 >= DATE(2024, 1, 1)) *
($A$2:$A$4824 < DATE(2024, 2, 1)) *
(
ISNUMBER(SEARCH("간질", $C$2:$C$4824)) +
ISNUMBER(SEARCH("기타", $C$2:$C$4824)) +
ISNUMBER(SEARCH("자폐성장애", $C$2:$C$4824)) +
ISNUMBER(SEARCH("지적", $C$2:$C$4824)) +
ISNUMBER(SEARCH("호흡기", $C$2:$C$4824)) +
ISNUMBER(SEARCH("휠체어", $C$2:$C$4824))
)
)

이렇게 해보세요.

첨부파일 : 단어별-추출.xlsx

@쭈꾸링 님 위의 조건읜 지적으로 시작되는데 "간질, 자폐성장애, 호흡기, 휠체어 "가 포함된다는것입니다.

혹시나. 간질, 자폐성장애, 호흡기, 휠체어 단어가 들어가거나 지적으로 시작되는 단어가 모두 포함된다는 의미이셨나요?
그러면 조건이 달라지니

=SUMPRODUCT(
($A$2:$A$4824>=DATE(2024,1,1))*
($A$2:$A$4824<DATE(2024,2,1))*
(
ISNUMBER(SEARCH("간질",$C$2:$C$4824))+
ISNUMBER(SEARCH("자폐성장애",$C$2:$C$4824))+
ISNUMBER(SEARCH("호흡기",$C$2:$C$4824))+
ISNUMBER(SEARCH("휠체어",$C$2:$C$4824))+
(LEFT($C$2:$C$4824,2)="지적")
))

이것처럼 하셔야 할겁니다

오히려 제가 잘 못알아들어서 죄송합니다 ㅠㅠ