매크로 열 잘라내고 붙여넣기 (정렬)

Sub RefineData()
    Dim vData As Variant, vTitle As Variant, vMatch As Variant, iC As Long
 
    Application.ScreenUpdating = False
    '// 원본자료를 배열로 가져오기
    vData = Worksheets("원본").UsedRange.Value2
    If Not IsArray(vData) Then Exit Sub
    If UBound(vData, 1) = 1 Then Exit Sub
 
    '// 표제목만 따로 배열 생성
    vTitle = Split("발주번호,발주일,입고예정일,출고일,발주유형,SKU 이름,SKU ID,물류센터,확정수량,단가,매입가,총발주 매입금", ",")
    vTitle = Application.Transpose(vTitle)
 
    '// 결과는 새 시트에 기록
    Worksheets.Add after:=Worksheets(Worksheets.Count)
 
    With ActiveSheet
        For iC = 1 To UBound(vTitle, 1)
            vMatch = Application.Match(vTitle(iC, 1), Application.Index(vData, 1), 0)
            If IsError(vMatch) Then                 '// 새로 생성할 열
                .Cells(1, iC) = vTitle(iC, 1)
            Else                                    '// 복제할 열
                .Cells(1, iC).Resize(UBound(vData, 1), 1) = Application.Index(vData, , vMatch)
            End If
        Next iC
 
        '// 셀서식 정리
        .Range("B:D").NumberFormat = "yyyy-mm-dd"   '// 날짜들
        .Range("I:L").NumberFormat = "#,##0"        '// 숫자들
        .Range("J:J").NumberFormat = "#,##0.00"     '// 단가만 1/100까지
        .Range("A:L").EntireColumn.AutoFit
        .Range("E:E,H:H").HorizontalAlignment = xlCenter
 
        '// 틀고정
        .Range("A2").Activate
        ActiveWindow.FreezePanes = True
        '// 조건부 서식
        With .Range("A:A")
            .FormatConditions.AddUniqueValues
            .FormatConditions(1).SetFirstPriority
            .FormatConditions(1).DupeUnique = xlDuplicate
            .FormatConditions(1).Font.Color = RGB(156, 0, 0)
            .FormatConditions(1).Interior.Color = RGB(255, 200, 200)
        End With
        '// 테두리
        With .Range("A1").CurrentRegion
            .BorderAround xlContinuous, xlThin
            .Borders(xlInsideHorizontal).LineStyle = xlContinuous
            .Borders(xlInsideVertical).LineStyle = xlContinuous
            .Borders(xlInsideHorizontal).Weight = xlThin
            .Borders(xlInsideVertical).Weight = xlThin
        End With
    End With
    Application.ScreenUpdating = True
 
End Sub