표 정리 VBA 질문 드립니다.

Sub RearrangeData()
    Dim sh1 As Worksheet, sh2 As Worksheet
    Dim vData As Variant, vCells As Variant, iR As Long, iC As Long, idx As Long
    '// 1번
    Const DataTotalColumns = 6, DataColumns = 2, DataRows = 8, DataStart = 2
 
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    Set sh1 = ActiveSheet
 
    '// 2번
    If Evaluate("IsRef('" & sh1.Name & "(정리)'!A1)") Then
        Application.DisplayAlerts = False
        Worksheets(sh1.Name & "(정리)").Delete
        Application.DisplayAlerts = True
    End If
    sh1.Copy after:=sh1
    Set sh2 = ActiveSheet
    sh2.Name = sh1.Name & "(정리)"
    sh2.UsedRange.ClearContents
 
 
    '// 3번
    vCells = sh1.Range(sh1.Cells(1, 1), sh1.UsedRange.SpecialCells(xlCellTypeLastCell)).Value2
 
    '// 4번의 순환문
    For iR = DataStart To UBound(vCells, 1) Step DataRows
    For iC = 1 To DataTotalColumns Step DataColumns
        If Trim(vCells(iR, iC)) <> "" Then
 
            '// 4번의 idx 숫자 증가
            idx = idx + 1
 
            '// 5번의 원본 임시 복사
            vData = sh1.Cells(iR, iC).Resize(DataRows, DataColumns).Value2
            '// 5번의 데이터 복사 
            sh2.Cells(Int((idx - 1) / (DataTotalColumns / DataColumns)) * DataRows + DataStart, _
            ((idx - 1) Mod (DataTotalColumns / DataColumns)) * DataColumns + 1).Resize(DataRows, DataColumns) = vData
 
        End If
    Next iC
    Next iR
    Application.EnableEvents = True
    Application.ScreenUpdating = True
 
End Sub