밑에 첨부파일 이용하시면 쉽게 따라하실 수 있으실 거에요.

윤아 란 검색어로 소녀시대 라는 결과를 찾을때

=LOOKUP(1,0/(C:C=G2),B:B)

위의 공식을 사용하시면 됩니다. 공식화 하자면

=LOOKUP(1,0/(조건1),결과범위)

이번에는 조건이 2개일때 입니다.

안유진,아이브  라는 조건으로 스타쉽 을 찾아 볼게요.

조건 1개일때
=LOOKUP(1,0/(C:C=G2),B:B)

조건 2개일때
=LOOKUP(1,0/(C:C=F4)/(B:B=G4),D:D)

/(조건2) 이런 식으로 조건을 추가해 주면 됩니다.(나누기 기호 반드시)

조건 3개 4개일 때도 마찬가지입니다.

이 방식은 XLOOKUP 과 호환이 잘됩니다.

=LOOKUP(1,0/(C:C=F4)/(B:B=G4),D:D)
=XLOOKUP(1,(C:C=F4)*(B:B=G4),D:D)

큰 차이 없죠? 0/ 부분 빼고 나머지 / 를 *  로 변환하면 그만입니다.

반대로 XLOOKUP -> LOOKUP 으로 변환도 가능합니다.

다만 완전히 똑같진 않습니다.

"윤아" 라는 검색했을 때 답이
20살, 25살, 31살 이렇게 3개가 있을때

LOOKUP 은 31살(마지막 값)
XLOOKUP 은 20살(첫번째 값)

저런 특징이 장점이라고 생각하고 잘 써먹고 있지만
사실은 오류인데 그걸 이용하고 있다는 생각이 들어 좀 찝찝한 부분도 있습니다.

한셀에서 저 공식을 사용할 경우
마지막 값이 아니라 첫번째 값을 반환하거든요.

좀 더 많은 정보를 원하신다면 정보 계시판에 아래 글 참고해주시면 됩니다.

LOOKUP 함수 사용법(2019 이하 필독)

마지막은 위에 소개한 XLOOKUP <-> LOOKUP 변환의 실제 예시입니다.
(Q&A 계시판 77864 번)

=LOOKUP(1,0/(ISNUMBER(FIND(공지메인!$H$1:$H$101,LOOKUP(1,0/(공지메인!$D$1:$D$101=C3),공지메인!$B$1:$B$101)))/(공지메인!$H$1:$H$101<>"")),공지메인!$H$1:$H$101)

=XLOOKUP(1,ISNUMBER(FIND(공지메인!$H$1:$H$101,XLOOKUP(C3,공지메인!$D$1:$D$20,공지메인!$B$1:$B$20)))*(공지메인!$H$1:$H$101<>""),공지메인!$H$1:$H$101)

저런 식으로 살짝 길고 복잡하더라도 규칙만 지켜주면 변환 잘 되더라구요.

아직 예외는 발견 못했습니다

지난번에 올린 LOOKUP 함수 사용법(2019 이하 필독) 의 경우
제가 중시하는 '유연성' 이란 내용 위주로 쓴 글이라
LOOKUP 함수가 익숙하지 않으신 분들께는 너무 어려울 수도 있겠다는 생각이 들어
이렇게 다시 올립니다.

기본적인 사용법이 너무 쉬워서 스킵했는데
쉽고 간단한 부분이 제대로 전달되지 않았다는 느낌이 들어 다시 올려요.

2019 이하 사용자분들께서는 많이 사용해 주셨으면 합니다.
아직까지 전 별다른 오류를 만나보진 못했네요.
혹시 오류 발견하신다면 제보 부탁드릴께요.