[퀴즈] 텍스트 나누기, ( 와 ) 사이는 제외하기

Function SmartSplit(inputStr As String) As Variant
    Dim result() As String
    Dim temp As String
    Dim depth As Integer
    Dim i As Integer
    Dim c As String
    Dim idx As Integer
    idx = 0
    ReDim result(0)
 
    For i = 1 To Len(inputStr)
        c = Mid(inputStr, i, 1)
        If c = "(" Then
            depth = depth + 1
            temp = temp & c
        ElseIf c = ")" Then
            depth = depth - 1
            temp = temp & c
        ElseIf c = "," And depth = 0 Then
            result(idx) = Trim(temp)
            temp = ""
            idx = idx + 1
            ReDim Preserve result(idx)
        Else
            temp = temp & c
        End If
    Next i
    result(idx) = Trim(temp)
    SmartSplit = result
End Function

=INDEX(SmartSplit($A2), COLUMN()-2)

Function SplitNest(txt As String, _
    Optional delim As String = ",", Optional openB As String = "(", Optional closeB As String = ")") As Variant
 
    Dim r() As String, t As String, i As Long, d As Long, c As String
    ReDim r(0)
 
    For i = 1 To Len(txt)
        c = Mid(txt, i, 1)
        If c = openB Then d = d + 1 Else If c = closeB Then d = d - 1
        If c = delim And d = 0 Then
            r(UBound(r)) = Trim(t): t = "": ReDim Preserve r(UBound(r) + 1)
        Else
            t = t & c
        End If
    Next i
 
    If Len(t) > 0 Then r(UBound(r)) = Trim(t)
    SplitNest = r
End Function