VBA 실행 파일 찾기 :: GetFileApplication 함수 사용법 및 전체 코드

Option Explicit
 
#If VBA7 Then
' https://docs.microsoft.com/en-us/windows/win32/api/shellapi/nf-shellapi-findexecutablea
Private Declare PtrSafe Function FindExecutable& Lib "shell32.dll" Alias "FindExecutableA" _
                                                                        (ByVal lpFile As String, _
                                                                        ByVal lpDirectory As String, _
                                                                        ByVal lpResult As String)
#Else
Private Declare Function FindExecutable& Lib "shell32.dll" Alias "FindExecutableA" _
                                                                        (ByVal lpFile As String, _
                                                                        ByVal lpDirectory As String, _
                                                                        ByVal lpResult As String)
#End If
 
'###############################################################
'오빠두엑셀 VBA 사용자지정함수 (https://www.oppadu.com/)
'■ GetFileApplication 함수
'■ 지정한 경로의 파일을 실행할 실행프로그램(*.exe)을 찾아 반환합니다.
'■ 인수 설명
'_____________sFile : 실행 프로그램을 찾을 파일의 파일경로입니다.
'###############################################################
 
Public Function GetFileApplication(ByVal sFile As String) As String
 
Dim i As Long: Dim E As String
 
If Dir(sFile) = "" Or sFile = "" Then GetFileApplication = "존재하지 않는 파일": Exit Function
If Len(sFile) > 260 Then GetFileApplication = "글자수 초과": Exit Function
 
' Windows 최대 허용 파일경로는 260자 입니다.
E = String(260, Chr(0))
 
i = FindExecutable(sFile, vbNullString, E)
 
' 실행 프로그램 있을 경우 32보다 큰 값을 반환합니다.
If i > 32 Then
    GetFileApplication = Left$(E, InStr(E, Chr$(0)) - 1)
Else
    GetFileApplication = "실행 파일 없음"
End If
 
End Function