엑셀 고유 번호 생성 :: RandBetweenUnique 함수 사용법

'###############################################################
'오빠두엑셀 VBA 사용자지정함수 (https://www.oppadu.com)
'▶ RandBetweenUnique 함수
'▶ 두 숫자 사이의 무작위 고유 숫자를 지정한 갯수만큼 생성하여 배열로 반환합니다.
'▶ 인수 설명
'_____________lngL             : 추출할 숫자의 최소값입니다.
'_____________lngU            : 추출할 숫자의 최대값입니다.
'_____________lngCount     : 추출할 고유숫자의 개수입니다.
'_____________Excludes      : 추출할 숫자 중 제외될 값이 입력된 배열 또는 범위입니다.
'###############################################################
 
Function RandBetweenUnique(lngL As Long, lngU As Long, Count As Long, Optional Excludes As Variant) As Variant
 
' 변수 설정
Dim dictList As Object: Dim dictExclude As Object
Dim Exclude As Variant
Dim i As Long: Dim j As Long
 
Set dictList = CreateObject("Scripting.Dictionary")
Set dictExclude = CreateObject("Scripting.Dictionary")
 
' 제외값 설정
If Not IsMissing(Excludes) Then
    For Each Exclude In Excludes
        If Not dictExclude.Exists(Exclude) Then dictExclude.Add Exclude, Exclude
    Next
End If
 
' 추출개수가 최대개수보다 클 경우 추출개수 재조정
If Count > lngU - lngL + 1 - dictExclude.Count Then Count = lngU - lngL + 1 - dictExclude.Count
 
' 무작위 값 생성
Do
    j = CLng(Rnd * (lngU - lngL)) + lngL
    If Not dictList.Exists(j) And Not dictExclude.Exists(j) Then
            dictList.Add j, j
            i = i + 1
    End If
Loop Until i = Count
 
'결과값 반환
RandBetweenUnique = dictList.Items
 
End Function